Skip to main content

bat файл быстрого переключения настроек сетевой карты

@echo off
chcp 65001 >nul
title Переключение сетевого интерфейса

:: === ИМЯ СЕТЕВОГО ИНТЕРФЕЙСА ===
set IFACE=Ethernet

:MENU
cls
echo ===============================
echo  Переключение сетевых настроек
echo ===============================
echo.
echo 1 - Статический IP
echo 2 - DHCP
echo.
echo 0 - Выход
echo.
set /p CHOICE=Выберите режим: 

if "%CHOICE%"=="1" goto STATIC
if "%CHOICE%"=="2" goto DHCP
if "%CHOICE%"=="0" exit

goto MENU

:STATIC
echo.
echo Установка статического IP...
netsh interface ip set address name="%IFACE%" static 10.44.100.200 255.255.255.0 10.44.100.1 1
netsh interface ip set dns name="%IFACE%" static 10.5.8.8
netsh interface ip add dns name="%IFACE%" 10.5.1.1 index=2
echo Готово.
pause
goto MENU

:DHCP
echo.
echo Включение DHCP...
netsh interface ip set address name="%IFACE%" dhcp
netsh interface ip set dns name="%IFACE%" static 77.88.8.8
netsh interface ip add dns name="%IFACE%" 8.8.8.8 index=2
echo Готово.
pause
goto MENU